Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Chapter 1 - El Pantano
Pantano is a decorated region.
Parte del pantano is a kind of habitacionDecorada.
[Para el comando salida debido a la lentitud en glulx de 'the best route' en este mapeado]
A parte del pantano has a direction called DirCuevas. The DirCuevas of a parte del pantano is usually south.
[Para complicar aún más el 'bonito' laberinto, los nombres y descripciones de muchas habitaciones son al 'azar']
The printed name of a parte del pantano is usually "[one of]Un lugar como otro cualquiera del pantano[or]Entre árboles del pantano[or]En el apestoso pantano Hapawa[or]En el barro del pantano[at random]".
The description of a parte del pantano is usually "[one of]Humedad, plantas sucias, probablemente, pestilencia. En definitiva el brumoso pantano de Hapawa. Ojalá salgamos pronto.[or]La luz se oculta tras las copas de los árboles y se difumina aún más con la sutil bruma que recorre el pantano. Uno no puede dejar de pensar que simplemente prefiere no entrar en este lugar abandonado.[or]Veamos... hay árboles, agua que tan pronto te llega al tobillo como a la cintura y sonidos extraños. En definitiva seguimos en el pantano y en su bruma.[or]Más y más plantas del pantano. Suelo del pantano. Sonidos del pantano. Árboles de manglar. Bruma de los pantanos. Probablemente olores del pantano. En definitiva, en algún lugar del pantano.[at random]".
[Todos las habitaciones del pantano tienen una serie de decorados iguales]
The decoracion of Pantano is Table of DecoPantano.
Table of DecoPantano
| topic | descripcion | printedName |
| "inmundicia" or "porqueria" or "musgo" or "musgos" or "suciedad" | "Cosas putrefactas que no apetece comerse, es decir, plantas muertas y putrefactas, por lo general, que no tienen ese magnífico olor a carne muerta. Claro que en tu estado poco puedes oler, es una de las cosas que peor sobrellevas." | "la inmundicia" |
| "pantano" or "cienagas" or "manglar" | "Aunque algunos de tus congéneres menores, sobre todo esos minúsculos dragones verdes de aliento pestilente, viven en los pantanos, por lo general cualquier dragón que se precie evitará vivir en estos lugares repletos agua y suciedad. Los seres que los habitan son lo más rastrero de entre los animales y las plantas." | "el pantano" |
| "bosque" | "Más que un bosque se trata de un manglar repleto de aguas estancadas." | "el bosque" |
| "aguas" or "agua" or "charco" or "charcos" or "humedad" | "Las aguas de este pantano, como el de todos, son sucias y pestilentes. Cuando un humano las cruza no puede verse sus propios pies. Sin embargo algunos de los habitantes de las aguas las encuentran lo bastante claras como para arrancarle los dedos al humano." | "el agua" |
| "putrefaccion" or "pestilencia" or "olores" | "Por suerte en tu estado no puedes oler nada, pero seguro que está por todas partes." | "la putrefaccion" |
| "criaturas" or "criatura" or "bestias" or "seres" | "Se escuchan en todas direcciones pero no las ves. Son bestias avergonzadas de su aspecto deplorable, así que huyen en cuanto cualquiera se les acerca." | "las criaturas del pantano" |
| "luz" | "Llamar luz a la penumbra que resulta tras atravesar las copas del manglar, es como una suerte de chiste cruel." | "la luz del pantano" |
| "bruma" or "niebla" or "neblina" | "Elevándose desde las cenagosas aguas una sempiterna nieblina lo desdibuja todo en este pantano." | "la bruma" |
A sonidos is a backdrop. It is everywhere.
Understand "sonido" as sonidos.
Instead of doing anything with sonidos:
try listening.
[Entretenerse a oler el pantano tiene que resultar desagradable]
Instead of smelling while in Pantano:
say "No puedes oler nada en este estado, pero tu portador sí... Veamos: [one of]olor a putrefacción.[or]olores extraños, probablemente de montones de esporas de todos esos musgos. ¿Serán tóxicos?.[or]puff, una mezcla de olores completamente insoportable. Suerte que no lo estás oliendo con tu propia nariz de dragón.[or]asqueroso, asqueroso... y... un poco más de asqueroso...[at random]No esperabas menos de este pantano.".
[Examina del suelo y del techo]
Instead of examining down while in Pantano:
if the location is Pantano17:
say "Todo lo que queda del viejo torreón. Un robusto y resistente suelo. No parece ser más que eso, un recuerdo del pasado.";
otherwise if the location is Pantano10:
say "[if Pantano10 is quemado]El suelo está negro de la ceniza.[otherwise]El cieno y el agua sucia están cubiertos aquí de una fina capa de telarañas pegajosas.[end if]";
otherwise if the location is Pantano26:
say "Esta tierra fue cultivada en el pasado por los humanos. Es evidente. Restos de surcos y montículos de tierra, vano intento de dominar a la naturaleza.";
if calabaza is off-stage and resuelto of Pantano26 is 0:
bnw;
say "¡Mira! ¡Una calabaza aún ha crecido por aquí! Igual resulta de utilidad.";
move calabaza to Pantano26;
change resuelto of Pantano26 to 1;
otherwise:
say "[one of]Aquí y allá hay algo de suelo seco cubierto de plantas, pero por lo general todos son charcos pestilentes.[or]Más que nada agua sucia.[or]Aguas oscuras en las que se ocultan criaturas menores.[at random]".
Instead of examining up while in Pantano:
say "[one of]No se puede ver más que fugazmente el anhelado cielo. Lo demás lo cubren las ramas de estos odiosos árboles.[or]Los árboles lo cubren casi todo transformando la luz en una sucia penumbra.[or]Buscas el cielo al que anhelas volver mirando hacia arriba, pero tan sólo puedes ver ramas de árboles.[at random]".
To examina direccion fortaleza:
say "No es que se vea realmente, pero estás casi seguro que en aquella dirección está la fortaleza de Sady Omú.".
To examina direccion sur:
say "No se ve nada desde aquí, pero estás casi seguro de que la entrada a las cavernas está en esa dirección.".
[Examinar una dirección]
Instead of examining a direction while in Pantano:
if location is Pantano14:
if noun is:
-- north:
examina direccion fortaleza;
-- northeast:
examina direccion fortaleza;
-- northwest:
examina direccion fortaleza;
-- south:
examina direccion sur;
-- southeast:
examina direccion sur;
-- southwest:
examina direccion sur;
-- otherwise:
say "En esa dirección no ves nada de interés.";
otherwise if location is PuertaCastillo:
if noun is:
-- north:
say "En esa dirección se levanta la fortaleza del nigromante. Altas torres sobre un foso de brea ardiente.";
-- south:
say "En esa dirección está el pantano, un manglar de árboles sucios y retorcidos.";
-- otherwise:
say "En esa dirección tan sólo pueden verse las paredes abruptas de la colina que sostiene a la fortaleza.";
otherwise if location is Copa:
if noun is:
-- north:
say "Lejos, sobresaliendo sobre el pantano se divisa lo que podría ser la fortaleza de Sady Omú.";
-- south:
say "Hay un pequeño claro en esa dirección.";
-- otherwise:
say "El pantano de Hapawa continúa interminable en esa dirección.";
otherwise if location is Pantano28:
if noun is:
-- north:
say "Hay un tunel horadado en la pared, en esa dirección.";
-- south:
say "Ahí te espera el pantano.";
-- otherwise:
say "En esa dirección sólo se ve la pared de roca impenetrable.";
[Verificamos varias cosas, una a una]
otherwise:
let destino be the room the noun from the location;
if the destino is Pantano1:
say "Se escucha un refrescante sonido de agua corriente en esa dirección.";
otherwise if the destino is Pantano10:
say "[if Pantano10 is quemado]Por allí el pantano parece quemado.[otherwise]No estás seguro, pero algo blanco parece cubrir el pantano en aquella dirección.[end if]";
otherwise if the destino is Pantano19:
say "Un hedor insoportable viene de esa dirección.";
otherwise if the destino is Pantano23:
say "En aquella dirección los animales callan, como si fuese irrespetuoso parlotear allí.";
otherwise if the destino is Pantano25:
say "Por un momento te ha parecido que los árboles mismos se movían en esa dirección, pero debe haber sido una ilusión óptica.";
otherwise if the destino is Pantano28:
say "Esa parte del pantano parece pegada a alguna clase de pared. Tal vez sea la base del castillo de Sady Omú, o sea tu destino.";
otherwise if deavork is in destino:
say "Las plantas en esa dirección se mueve, tiemblan, como si algo las estuviese zarandeando.";
otherwise if lobo is in destino and hambre of lobo is greater than 15:
say "De entre las plantas en esa dirección se escuchan quejidos lastimosos.";
otherwise if there is a orco in the destino:
say "En esa dirección no parece haber más que plantas como en todas direcciones, aunque es cierto que cierto tufo especialmente apestoso viene desde allí.";
otherwise if icalante is in destino and icalante is enfadado:
say "Desde esa dirección parecen venir extraños gruñidos y quejidos inhumanas.";
otherwise:
say "Plantas, plantas y más plantas del pantano, eso es todo lo que se ve.".
A rama_falsa is a backdrop. It is in Pantano. The printed name of rama_falsa is "rama". It is female.
Understand "rama" as rama_falsa when rama is not visible and rama_arbol is not visible.
Before taking rama_falsa when rama is not visible:
move rama to location;
say "Quiebras una de las ramas de uno de los árboles del pantano.".
Instead of taking rama_falsa:
try taking rama.
Some arboles_general is a backdrop. It is in Pantano. The printed name of arboles_general is "árboles".
Understand "arbol" or "arboles" or "frondosidad" or "copas" or "plantas" or "vegetación" as arboles_general when recio arbol is not visible.
The description of arboles_general is "Son árboles del pantano, no importa si están vivos o muertos, siempre están recubiertos de enormes cantidades de musgo u otras cosas peores, todas ellas clasificables dentro de la categoría de porquería. Bueno, algunas tal vez mereciesen la categoría de inmundicia.".
Instead of taking arboles_general:
say "Coger los árboles del pantano... buena idea, y de paso quemarlos a todos y destruir este lugar apestoso... Ojalá se pudiese, ¡ojalá!.".
Instead of climbing or entering arboles_general:
say "Trepar aquí no parece tener mucho sentido y sería bastante arriesgado. Parece fácil resbalarse en estos troncos y ramas cubiertos de musgos húmedos.".
Rule for supplying a missing noun while climbing:
if the location is in Pantano:
change noun to arboles_general.